How to use Virtuoso:
install in windows:
install in linux
install in linux step by step
RDF in Virtuoso (table, and sparql)
bulk upload RDF

Chem2Bio2RDF link:
http://cheminfov.informatics.indiana.edu:8890/sparql (more stable and faster), see sparlql examples in cheminfov virtuoso
Use HTTP to query and retrieve data:
http://chem2bio2rdf.org:8890/sparql?query=select distinct ?Concept where {[] a ?Concept}&format=xmll&debug=on&timeout=

Some sample SPARQL:
1) find drug targets

PREFIX compound: <http://chem2bio2rdf.org/rdf/vocab/resource/compound/>
PREFIX drugbank_drug:
<http://chem2bio2rdf.org/rdf/vocab/resource/drugbank_drug/>
PREFIX drugbank_interaction:
<http://chem2bio2rdf.org/rdf/vocab/resource/drugbank_interaction/>
PREFIX gene: <http://chem2bio2rdf.org/rdf/vocab/resource/gene/>
 
SELECT ?compound_cid ?geneSymbol
FROM <http://chem2bio2rdf.org/sample>
WHERE
 {
   ?compound compound:CID ?compound_cid . FILTER
(?compound_cid=123631 or ?compound_cid=84836) .
   ?drug drugbank_drug:CID ?compound .
   ?drugtarget drugbank_interaction:DBID ?drug .
   ?drugtarget drugbank_interaction:geneSymbol  ?gene .
   ?gene  gene:geneSymbol  ?geneSymbol .
 
 }
 

below is run in cheminfov
PREFIX compound: <http://chem2bio2rdf.org/pubchem/resource/>
PREFIX drugbank: <http://chem2bio2rdf.org/drugbank/resource/>
PREFIX uniprot: <http://chem2bio2rdf.org/uniprot/resource/>
 
SELECT ?compound_cid  ?geneSymbol
FROM <http://chem2bio2rdf.org/pubchem>
FROM <http://chem2bio2rdf.org/drugbank>
FROM <http://chem2bio2rdf.org/uniprot>
WHERE
 {
   ?compound compound:CID ?compound_cid . FILTER
(?compound_cid=123631 or ?compound_cid=84836) .
   ?drug drugbank:CID ?compound .
   ?target drugbank:DBID ?drug .
   ?target drugbank:gene ?gene .
   ?gene  uniprot:geneSymbol  ?geneSymbol .
 
 }
 

2) drug target network
PREFIX compound: <http://chem2bio2rdf.org/rdf/vocab/resource/compound/>
PREFIX drugbank_drug:
<http://chem2bio2rdf.org/rdf/vocab/resource/drugbank_drug/>
PREFIX drugbank_interaction:
<http://chem2bio2rdf.org/rdf/vocab/resource/drugbank_interaction/>
PREFIX gene: <http://chem2bio2rdf.org/rdf/vocab/resource/gene/>
 
SELECT ?compound_cid ?geneSymbol
FROM <http://chem2bio2rdf.org/sample>
WHERE
 {
   ?compound compound:CID ?compound_cid .
   ?drug drugbank_drug:CID ?compound .
   ?drugtarget drugbank_interaction:DBID ?drug .
   ?drugtarget drugbank_interaction:geneSymbol  ?gene .
   ?drugtarget drugbank_interaction:human ?human . FILTER (?human="1") .
   ?gene  gene:geneSymbol  ?geneSymbol .
 } group by ?compound_cid ?geneSymbol
3) chemogenomics data
PREFIX compound: <http://chem2bio2rdf.org/rdf/vocab/resource/compound/>
PREFIX gene: <http://chem2bio2rdf.org/rdf/vocab/resource/gene/>
PREFIX interaction: <http://chem2bio2rdf.org/rdf/vocab/resource/chemogenomics/>
select ?compound_cid ?geneSymbol ?med_interested ?source
from <http://chem2bio2rdf.org/chem2bio2rdf_chemogenomics>
where {
?compound compound:CID ?compound_cid . FILTER (?compound_cid=1000)
?interaction interaction:CID ?compound .
?interaction interaction:med_interested ?med_interested .
?interaction interaction:primary_source ?source .
?interaction interaction:GENE ?gene .
?gene  gene:geneSymbol  ?geneSymbol . FILTER (?geneSymbol="ADRA1A")
}
 
4) from sider to kegg pathway
PREFIX sider: <http://chem2bio2rdf.org/rdf/vocab/resource/sider/>
PREFIX drugbank_interaction: <http://chem2bio2rdf.org/rdf/vocab/resource/drugbank_interaction/>
PREFIX drugbank_drug: <http://chem2bio2rdf.org/rdf/vocab/resource/drugbank_drug/>
PREFIX kegg_pathway_protein: <http://chem2bio2rdf.org/rdf/vocab/resource/kegg_pathway_protein/>
 
SELECT ?side_effect ?compound ?drug ?uniprot ?pathway_id
from <http://chem2bio2rdf.org/sample>
WHERE {
 ?sider2compound sider:side_effect ?side_effect .  FILTER regex(?side_effect,"hepatomegaly","i") .
 ?sider2compound sider:cid ?compound .
 
 ?drug drugbank_drug:CID ?compound .
 ?drug2target drugbank_interaction:DBID ?drug .
 ?drug2target drugbank_interaction:SwissProt_ID ?uniprot .
 
 ?kegg_pathway kegg_pathway_protein:Uniprot ?uniprot .
 ?kegg_pathway kegg_pathway_protein:PathwayID ?pathway_id .
 
}