Side effect associated targets:
PREFIX bibo: <http://purl.org/ontology/bibo/>
PREFIX chembl: <http://rdf.farmbio.uu.se/chembl/onto/#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX cito: <http://purl.org/spar/cito/>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX bo: <http://www.blueobelisk.org/chemistryblogs/>
PREFIX sider: <http://chem2bio2rdf.org/sider/resource/>
PREFIX pubchem: <http://chem2bio2rdf.org/pubchem/resource/>
PREFIX hprd: <http://chem2bio2rdf.org/hprd/resource/>
 
 
SELECT distinct ?mol ?title
from <http://semantics.bigcat.unimaas.nl/chembl13>
from <http://chem2bio2rdf.org/sider>
from <http://chem2bio2rdf.org/pubchem>
from <http://chem2bio2rdf.org/hprd>
 
WHERE {
  ?sider sider:cid [pubchem:std_inchi ?inchi] .
  ?sider sider:side_effect ?side_effect . FILTER regex(?side_effect,"hypertension","i") .
  ?mol bo:inchi ?inchi .
 
  ?act chembl:forMolecule ?mol .
  ?act chembl:type ?type ;
    chembl:standardValue ?value ;
    chembl:standardUnits "nM" ;
    chembl:type "IC50" ;
    chembl:onAssay ?assay .
 
  FILTER(?value<10000) .
  ?assay chembl:hasTarget ?target .
  ?target dc:title ?title .
  ?target chembl:organism "Homo sapiens"
}

Associate target with side effect via protein protein interaction
PREFIX bibo: <http://purl.org/ontology/bibo/>
PREFIX chembl: <http://rdf.farmbio.uu.se/chembl/onto/#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX cito: <http://purl.org/spar/cito/>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX bo: <http://www.blueobelisk.org/chemistryblogs/>
PREFIX sider: <http://chem2bio2rdf.org/sider/resource/>
PREFIX pubchem: <http://chem2bio2rdf.org/pubchem/resource/>
PREFIX hprd: <http://chem2bio2rdf.org/hprd/resource/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
 
SELECT *
from <http://semantics.bigcat.unimaas.nl/chembl13>
from <http://chem2bio2rdf.org/sider>
from <http://chem2bio2rdf.org/pubchem>
from <http://chem2bio2rdf.org/hprd>
from <http://chem2bio2rdf.org/uniprot>
 
WHERE {
 
   ?sider sider:cid [pubchem:std_inchi ?inchi] .
   ?sider sider:side_effect ?side_effect .  FILTER regex(?side_effect,"hypertension","i") .
   ?mol bo:inchi ?inchi .
 
  ?act chembl:forMolecule ?mol .
  ?act chembl:type ?type ;
    cito:citesAsDataSource ?paper ;
    chembl:standardValue ?value ;
    chembl:standardUnits "nM";
    chembl:type "IC50";
 
    chembl:onAssay ?assay .
  FILTER (xsd:float(?value)<10000) .
  ?assay chembl:hasTarget ?target .
  ?target dc:title ?title .
  ?target chembl:organism "Homo sapiens" .
  ?target owl:sameAs ?target_bio2rdf .
 
  ?interaction hprd:Uniprot_A [owl:sameAs ?target_bio2rdf] .
  ?interaction hprd:uniprot_B [owl:sameAs ?target_b] .
 
}



Find evidence in Medline:
PREFIX medline: <http://chem2bio2rdf.org/medline/resource/>
PREFIX uniprot: <http://chem2bio2rdf.org/uniprot/resource/>
PREFIX sider: <http://chem2bio2rdf.org/sider/resource/>
 
select distinct ?pmid
from <http://chem2bio2rdf.org/medline>
from <http://chem2bio2rdf.org/uniprot>
from <http://chem2bio2rdf.org/sider>
 
where
{
 ?pmid medline:gene [uniprot:geneSymbol "TP53"] .
 ?pmid  medline:side_effect ?sider .
 ?sider sider:side_effect ?side_effect .  FILTER regex(?side_effect,"cancer","i") .
}